Форум за електроника

[hunterS]

Здравейте, нов съм тука и искам да ви помоля за услуга написах си код за PIC16F84A и ме интересува дали е верен или имам грешка значи принципът на действие е следния: при подаване на захранване на PORTB1 и PORTB3 трябва да има 0 а на PORTB2 и PORTB4 да има 1 при постъпване на 0 на PORTB5 трябва PORTB1 да се установи в 1 а PORTB2 в 0 при което се задейства времезадръжка от 16ms след това портовете 1 и 2 се обръщат в първоначалното си състояние същия ефект е и с другите два порта 3 и 4 при постъпване на 0 на PORTB6. Кода е на Асемблер и моля ако някой има възможност за помощ защото които и да питам като чуе за Асемблер и се спича регнал съм се в друг форум ама там от умрял писмо да чакаш та ето го и кода и предварително ви благодаря


list p=16F84A ;ЗАДАВА ТИПА НА ПРОЦЕСОРА
#include <p16F84A.inc>; ДЕФИНИЦИИ НА SFR РЕГИСТРИТЕ
__CONFIG _CP_OFF & _WDT_OFF & _PWRTE_ON & _XT_OSC
;********************* Дефиниране на константи и променливи **************************
w EQU 0
f EQU 1
Counter EQU H'0C'

;--------------------- Дефиниране на входно-изходните портове ------------------------
#define Out_1 PORTB,1
#define Out_2 PORTB,2
#define Out_3 PORTB,3
#define Out_4 PORTB,4
#define In_l PORTB,5
#define In_r PORTB,6
;*************************************************************************************
; Потребителска програма
;*************************************************************************************
ORG H'0000' ;Вектор на начално установяване НУ
goto start ;Преход към начало на програмата
;*************************************************************************************
; Начало на програмата
;*************************************************************************************
start bsf STATUS,RP0 ;Избор на Банка 1
movlw B'00010100' ;Нулиране на 7 бит от регистър OPTION_REG-
movwf OPTION_REG ;разрешава включване на PULL-UP резистори
bcf STATUS,RP0 ;Избор на Банка 0
clrf PORTB ;Нулиране на PORTB
bsf STATUS,RP0 ;Избор на Банка 1
movlw B'11100000'
movwf TRISB ;RB7-RB5-Входове,RB0-RB4-Изход
bcf STATUS,RP0 ;Избор на Банка 0
goto main
;*************************************************************************************
; Използвани подпрограми
;*************************************************************************************
;--------------- Подпрограма "Wait" формира времезадръжка от 16ms --------------------
Wait movlw D'2' ;
movwf Counter ;
clrf TMR0 ;Нулира TMR0
again bcf INTCON,T0IF ;Нулира бит T0IF
loop btfss INTCON,T0IF ;Бит T0IF=1
goto loop ;Не,провери отново
decfsz Counter,f ;
goto again ;Изпълни цикъла отново
return
;*************************************************************************************
; Главна програма
;*************************************************************************************
main bcf Out_1 ;Установи PORTB,1 в 0
bsf Out_2 ;Установи PORTB,2 в 1
bcf Out_3 ;Установи PORTB,3 в 0
bsf Out_4 ;Установи PORTB,4 В 1
check_sensor
btfss In_l ;Провери PORTB,5 пропусни при 1
goto left ;Да,завой на дясно
btfss In_r ;Провери PORTB,6 пропусни при 1
goto right ;Да,завой на ляво
goto check_sensor ;Започни сканирането отначало
left
bsf Out_1 ;Установи PORTB,1 в 1
bcf Out_2 ;Установи PORTB,2 в 0
call Wait ;Изчакай 16ms
btfsc In_l ;Още ли иам препядствие
goto main ;Не,започни сканирането отначало
lsensor_release
btfss In_l ;Провери PORTB,5 пропусни при 1
goto lsensor_release ;Не,провери отново
call Wait ;Изчакай 16ms
goto main ;Започни сканирането отначало
right
bsf Out_3 ;Установи PORTB,3 в 1
bcf Out_4 ;Установи PORTB,4 в 0
call Wait ;Изчакай 16ms
btfsc In_r ;Още ли иам препядствие
goto main ;Не,започни сканирането отначало
rsensor_release
btfss In_r ;Провери PORTB,6 пропусни при 1
goto rsensor_release ;Не,провери отново
call Wait ;Изчакай 16ms
goto main ;Започни сканирането отначало
END

[andrey1988]

MPLAB нема ли симулация , пусни го там проследи къде какво става и ше видиш дали работи верно.

[hunterS]

Ми аз го пуснах през дебъгера и искарах листа кадето наблюдавах портовете наистина постъпват изминения на портовете но както споменах съм нов тоест в програмирането съм неопитен и за това ви моля за съдействие по темата.

[emil74]

Програмата трябва да работи коректно, така написана, доколкото виждам.

[hunterS]

Да идеята е когато на PORTB,5 имам 0 да завие надясно а при 0 на PORTB,6 да е наляво. А що се отнася за птекъсванията от PORTB да чувал съм че е по добре за да не се осложнява програмата и да не се мъчи процесора да проверява постоянно портовете но не съм наясно с тези прекъсвания

[emil74]

Извинявай, изтрих междувременно част от поста, защото прочетох обяснението най-отгоре.

Връщам го, за да разберат останалите защо ми отговаряш така:

Малко изпускам идеята тук:
Така написано:

btfss In_l ;Провери PORTB,5 пропусни при 1
goto left ;Да,завой на дясно
btfss In_r ;Провери PORTB,6 пропусни при 1
goto right ;Да,завой на ляво

ще имаш:

При PORTB,5=0 =>завой надясно
При PORTB,6=0 =>завой наляво

Логиката е:

btfss In_l ;PORTB,5=1?
goto left ; Не, завий наляво (т.е. ако не е 1, което значи, че е 0)
Същото е и за надясно.
При процедурите за наляво и надясно също при проверка за излизане
имаш обърната логика.
Това ли целиш?
Изтеглящите резистори на PORTB са pull-up, а не pull-down, нали знаеш? От OPTION REGISTER си ги разрешил, така че постоянно имаш високо ниво(1) на входовете на PORTB, когато не е натиснат бутон.

...
Мисля, че просто малко неясно си дал обясненията. Програмата трябва да работи коректно, така написана, доколкото виждам.


За прекъсванията, можеш да използваш готови програмки от същата книжка(на Н.Кенаров, струва ми се ). Ако използваш и "събуждане", ще намалиш консумацията.

[hunterS]

Много ти благодаря можвш ли да ми кажеш нещо за прекъсванията как по лесно да ги асимилирам че нещо не мога да се ориантирам.

Да ти си прав логиката е както ти си я написъл просто съм се подвел вместо ДА е трябвало да е НЕ моя грешка

Събирам ти двата поста-друг път не пускай пост след пост,а ползвай бутона EDIT

[emil74]

Изпълнението на всяка програма може да бъде прекратено при определени условия-настъпване на събитие от непрограмен характер в произволен момент(например натискане на бутон). При това може настъпването на такова събитие да се отрази на поведението на програмата като цяло. Един вид: Входно въздействие->изходна реакция. Разбира се, има дефинирани условия, които могат да предизвикват прекъсване. За промяна на PORTB това са: 1. При промяна фронта на сигнала на бит 0-> PORTB,0 или 2. Прекъсване при промяна на PORTB4,5,6,7 (не 0,1,2,3). За намалена консумация се ползва sleep, като се прави безкраен цикъл като основна програма:

main sleep
nop
goto main

Прави се програма за обслужване на прекъсванията, която проверява достоверността на прекъсването и насочва към съответна процедура.


Основното е да се запознаеш с кода на програми с прекъсвания. Обръщай внимание винаги да се възстановяват регистрите при излизане от прекъсването.

[hunterS]

Много ти благодаря Евала на хора като теб които искат да помогнат.

[RM]

Ето ти верния код: